Option Explicit

Sub MeuWebScraper()
    
    Dim http        As New MSXML2.ServerXMLHTTP60   ' Objeto usado para fazer requisições HTTP. Permite que você acesse e baixe páginas da web.
    Dim html        As New MSHTML.HTMLDocument      ' Objeto que representa um documento HTML. Usado para parsear e acessar elementos da página da web baixada.
    Dim pet         As Object                       ' Objeto para armazenar os nomes dos pet shops extraídos da página da web.
    Dim endereco    As Object                       ' Objeto para armazenar os endereços dos pet shops extraídos da página da web.
    Dim tel         As Object                       ' Objeto para armazenar os números de telefone dos pet shops extraídos da página da web.
    Dim Pl          As Worksheet                    ' Representa a planilha do Excel onde os dados raspados serão armazenados.
    Dim i           As Integer                      ' Variável de controle para o loop principal que itera através das páginas da web.
    Dim uLin        As Long                         ' Representa a última linha usada na planilha do Excel. Usado para determinar onde inserir novos dados.
    Dim URL         As String                       ' String que armazena a URL da página da web que está sendo raspada.
    Dim nPag        As Integer                      ' Representa o número total de páginas que serão raspadas.
    Dim j           As Integer                      ' Variável de controle para o loop interno que itera através dos elementos extraídos em uma única página da web.
    
    ' Define a planilha de destino onde os dados raspados serão armazenados.
    Set Pl = ThisWorkbook.Sheets("Planilha1")
    
    ' Define o número total de páginas que serão raspadas.
    nPag = 5

    On Error Resume Next
    For i = 1 To nPag
    
        URL = "https://www.telelistas.net/pa/belem/pet+shops?pag=" & i
        
        ' Estabelece uma conexão com a página da web e recupera seu conteúdo.
        http.Open "GET", URL, False
        http.setRequestHeader "User-Agent", "Mozilla/5.0"
        http.send
        
        ' Carrega o conteúdo da página no objeto HTML para posterior extração.
        html.body.innerHTML = http.responseText

        ' Identifica e extrai os elementos desejados da página da web.
        Set pet = html.getElementsByClassName("card-title loga-class go-info")
        Set endereco = html.getElementsByClassName("card-text text-muted")
        Set tel = html.getElementsByClassName("botao loga-class ver-tel")
        
        ' Itera através dos elementos extraídos e os armazena na planilha.
        For j = 0 To pet.Length - 1
            uLin = Pl.Cells(Pl.Rows.Count, "A").End(xlUp).Row
            Pl.Cells(uLin + 1, 1).Value = pet.Item(j).innerText
            Pl.Cells(uLin + 1, 2).Value = endereco.Item(j).innerText
            Pl.Cells(uLin + 1, 3).Value = tel.Item(j).getAttribute("data-telefone")
        Next j

    Next i
    
    ' Limpa e libera os objetos utilizados.
    Set http = Nothing
    Set html = Nothing
    Set Pl = Nothing
    Set pet = Nothing
    Set endereco = Nothing
    Set tel = Nothing

End Sub